// This work is licensed under Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International  

//@version=6
indicator("Modjoy-Error", "MS Trend Matrix [BigBeluga]", overlay = true, max_lines_count = 500, max_labels_count = 500)

// ＩＮＰＵＴＳ ――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――{

msLen          = input.int(10, "Market Structure Length", tooltip = "The lookback and lookahead period for detecting pivot highs and lows used for market structure.")
atrLength      = input.int(14, "ATR Length", tooltip = "The period used to calculate the Average True Range for the trailing stop and target spacing.")
atrMult        = input.float(4.0, "ATR Multiplier", tooltip = "Multiplied by ATR to determine the distance of the trailing stop from the price.")
targetStepMult = input.float(2.0, "Target Step (ATR Multiplier)", tooltip = "Determines the vertical distance between consecutive infinite targets based on ATR.")

bullColor      = input.color(color.rgb(52, 230, 126), "Bullish Color", tooltip = "Color used for bullish market structure, targets, and trailing stops.")
bearColor      = input.color(color.rgb(255, 82, 241), "Bearish Color", tooltip = "Color used for bearish market structure, targets, and trailing stops.")

showHistory    = input.bool(true, "Show Target History", tooltip = "When disabled, historical target lines and percentage labels will be hidden, leaving only the active target.")
showStop       = input.bool(true, "Show Trailing Stop", tooltip = "Toggle the visibility of the ATR Trailing Stop line and background fill.")

// }




// ＣＡＬＣＵＬＡＴＩＯＮＳ――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――{

ph = ta.pivothigh(msLen, msLen)
pl = ta.pivotlow(msLen, msLen)

var float phVal = na 
var float plVal = na
var int phIndx = 0
var int plIndx = 0
var bool direction = false 

float atr = ta.atr(atrLength)
var float atrTS = na

var float entryPrice = na
var float currentTarget = na
var line targetLine = na
var int trendStart = 0

// Arrays to track lines and labels for current trend cleanup
var line[]  targetLines  = array.new_line()
var label[] targetLabels = array.new_label()

// Function to clear arrays (old trend targets)
clearCurrentTrendObjects() =>
    if array.size(targetLines) > 0
        for i = 0 to array.size(targetLines) - 1
            line.delete(array.get(targetLines, i))
        array.clear(targetLines)
    if array.size(targetLabels) > 0
        for i = 0 to array.size(targetLabels) - 1
            label.delete(array.get(targetLabels, i))
        array.clear(targetLabels)

if not na(ph)
    phVal := high[msLen]
    phIndx := bar_index[msLen]

if not na(pl)
    plVal := low[msLen]
    plIndx := bar_index[msLen]


if ta.crossover(close, phVal) and not direction
    direction := true 
    atrTS := close - (atr * atrMult)
    entryPrice := phVal
    currentTarget := entryPrice + (atr * targetStepMult)
    trendStart := bar_index

    line.new(phIndx, phVal, bar_index, phVal, color=bullColor, width = 2)
    label.new(int(math.avg(phIndx, bar_index)), phVal, "ChoCh ↑", style = label.style_label_down, color = na, textcolor = bullColor)
    
    line.delete(targetLine)
    targetLine := line.new(bar_index, currentTarget, bar_index + 10, currentTarget, color=color.new(bullColor, 0), width=1)


if ta.crossunder(close, plVal) and direction
    direction := false 
    atrTS := close + (atr * atrMult)
    entryPrice := plVal
    currentTarget := entryPrice - (atr * targetStepMult)
    trendStart := bar_index

    line.new(plIndx, plVal, bar_index, plVal, color=bearColor, width = 2)
    label.new(int(math.avg(plIndx, bar_index)), plVal, "ChoCh ↓", style = label.style_label_up, color = na, textcolor = bearColor)
    
    line.delete(targetLine)
    targetLine := line.new(bar_index, currentTarget, bar_index + 10, currentTarget, color=color.new(bearColor, 0), width=1)


directionChange = direction != direction[1]

if directionChange and not showHistory
    clearCurrentTrendObjects()


if direction
    atrTS := math.max(nz(atrTS, close - (atr * atrMult)), close - (atr * atrMult))
    
    if high >= currentTarget and not na(currentTarget)
        line.set_x2(targetLine, bar_index)
        line.set_style(targetLine, line.style_dashed)
        line.set_x1(targetLine, trendStart)

        array.push(targetLines, targetLine)
        perc = (currentTarget - entryPrice) / entryPrice * 100
        array.push(targetLabels, label.new(trendStart, currentTarget, str.format("+{0,number,#.##}%", perc), style=label.style_none, textcolor=bullColor, size=size.small))

        currentTarget := currentTarget + (atr * targetStepMult)
        targetLine := line.new(trendStart, currentTarget, bar_index + 10, currentTarget, color=color.new(bullColor, 40), width=1)
    else
        line.set_x2(targetLine, bar_index + 10)

else
    atrTS := math.min(nz(atrTS, close + (atr * atrMult)), close + (atr * atrMult))
    
    if low <= currentTarget and not na(currentTarget)
        line.set_x2(targetLine, bar_index)
        line.set_style(targetLine, line.style_dashed)
        line.set_x1(targetLine, trendStart)
        
        array.push(targetLines, targetLine)
        perc = (currentTarget - entryPrice) / entryPrice * 100
        array.push(targetLabels, label.new(trendStart, currentTarget, str.format("{0,number,#.##}%", perc), style=label.style_none, textcolor=bearColor, size=size.small))

        currentTarget := currentTarget - (atr * targetStepMult)
        targetLine := line.new(trendStart, currentTarget, bar_index + 10, currentTarget, color=color.new(bearColor, 40), width=1)
    else
        line.set_x2(targetLine, bar_index + 10)

// }




// ＰＬＯＴ ――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――――{

plot(showStop and not directionChange ? atrTS : na, "ATR Trailing Stop", 
     color = direction ? bullColor : bearColor, 
     style = plot.style_linebr, 
     linewidth = 2)

plot_price = plot(close, display = display.none, editable = false)
plot_stop  = plot(showStop ? atrTS : na, display = display.none, editable = false)

fillCol = direction ? color.new(bullColor, 70) : color.new(bearColor, 70)

fill(plot_price, plot_stop, close, atrTS, na, showStop ? fillCol : na)

// }